dslinux/user/perl/lib/Time Local.pm Local.t gmtime.pm gmtime.t localtime.pm localtime.t tm.pm
cayenne
dslinux_cayenne at user.in-berlin.de
Mon Dec 4 18:01:17 CET 2006
Update of /cvsroot/dslinux/dslinux/user/perl/lib/Time
In directory antilope:/tmp/cvs-serv17422/lib/Time
Added Files:
Local.pm Local.t gmtime.pm gmtime.t localtime.pm localtime.t
tm.pm
Log Message:
Adding fresh perl source to HEAD to branch from
--- NEW FILE: localtime.pm ---
package Time::localtime;
use strict;
use 5.006_001;
use Time::tm;
our(@ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS, $VERSION);
BEGIN {
use Exporter ();
@ISA = qw(Exporter Time::tm);
@EXPORT = qw(localtime ctime);
@EXPORT_OK = qw(
$tm_sec $tm_min $tm_hour $tm_mday
$tm_mon $tm_year $tm_wday $tm_yday
$tm_isdst
);
%EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
$VERSION = 1.02;
}
use vars @EXPORT_OK;
sub populate (@) {
return unless @_;
my $tmob = Time::tm->new();
@$tmob = (
$tm_sec, $tm_min, $tm_hour, $tm_mday,
$tm_mon, $tm_year, $tm_wday, $tm_yday,
$tm_isdst )
= @_;
return $tmob;
}
sub localtime (;$) { populate CORE::localtime(@_ ? shift : time)}
sub ctime (;$) { scalar CORE::localtime(@_ ? shift : time) }
1;
__END__
=head1 NAME
Time::localtime - by-name interface to Perl's built-in localtime() function
=head1 SYNOPSIS
use Time::localtime;
printf "Year is %d\n", localtime->year() + 1900;
$now = ctime();
use Time::localtime;
use File::stat;
$date_string = ctime(stat($file)->mtime);
=head1 DESCRIPTION
This module's default exports override the core localtime() function,
replacing it with a version that returns "Time::tm" objects.
This object has methods that return the similarly named structure field
name from the C's tm structure from F<time.h>; namely sec, min, hour,
mday, mon, year, wday, yday, and isdst.
You may also import all the structure fields directly into your namespace
as regular variables using the :FIELDS import tag. (Note that this still
overrides your core functions.) Access these fields as
variables named with a preceding C<tm_> in front their method names.
Thus, C<$tm_obj-E<gt>mday()> corresponds to $tm_mday if you import
the fields.
The ctime() function provides a way of getting at the
scalar sense of the original CORE::localtime() function.
To access this functionality without the core overrides,
pass the C<use> an empty import list, and then access
function functions with their full qualified names.
On the other hand, the built-ins are still available
via the C<CORE::> pseudo-package.
=head1 NOTE
While this class is currently implemented using the Class::Struct
module to build a struct-like class, you shouldn't rely upon this.
=head1 AUTHOR
Tom Christiansen
--- NEW FILE: gmtime.t ---
#!./perl
BEGIN {
chdir 't' if -d 't';
@INC = '../lib';
}
BEGIN {
our $hasgm;
eval { my $n = gmtime 0 };
$hasgm = 1 unless $@ && $@ =~ /unimplemented/;
unless ($hasgm) { print "1..0 # Skip: no gmtime\n"; exit 0 }
}
BEGIN {
our @gmtime = gmtime 0; # This is the function gmtime.
unless (@gmtime) { print "1..0 # Skip: gmtime failed\n"; exit 0 }
}
print "1..10\n";
use Time::gmtime;
print "ok 1\n";
my $gmtime = gmtime 0 ; # This is the OO gmtime.
print "not " unless $gmtime->sec == $gmtime[0];
print "ok 2\n";
print "not " unless $gmtime->min == $gmtime[1];
print "ok 3\n";
print "not " unless $gmtime->hour == $gmtime[2];
print "ok 4\n";
print "not " unless $gmtime->mday == $gmtime[3];
print "ok 5\n";
print "not " unless $gmtime->mon == $gmtime[4];
print "ok 6\n";
print "not " unless $gmtime->year == $gmtime[5];
print "ok 7\n";
print "not " unless $gmtime->wday == $gmtime[6];
print "ok 8\n";
print "not " unless $gmtime->yday == $gmtime[7];
print "ok 9\n";
print "not " unless $gmtime->isdst == $gmtime[8];
print "ok 10\n";
--- NEW FILE: gmtime.pm ---
package Time::gmtime;
use strict;
use 5.006_001;
use Time::tm;
our(@ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS, $VERSION);
BEGIN {
use Exporter ();
@ISA = qw(Exporter Time::tm);
@EXPORT = qw(gmtime gmctime);
@EXPORT_OK = qw(
$tm_sec $tm_min $tm_hour $tm_mday
$tm_mon $tm_year $tm_wday $tm_yday
$tm_isdst
);
%EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
$VERSION = 1.02;
}
use vars @EXPORT_OK;
sub populate (@) {
return unless @_;
my $tmob = Time::tm->new();
@$tmob = (
$tm_sec, $tm_min, $tm_hour, $tm_mday,
$tm_mon, $tm_year, $tm_wday, $tm_yday,
$tm_isdst )
= @_;
return $tmob;
}
sub gmtime (;$) { populate CORE::gmtime(@_ ? shift : time)}
sub gmctime (;$) { scalar CORE::gmtime(@_ ? shift : time)}
1;
__END__
=head1 NAME
Time::gmtime - by-name interface to Perl's built-in gmtime() function
=head1 SYNOPSIS
use Time::gmtime;
$gm = gmtime();
printf "The day in Greenwich is %s\n",
(qw(Sun Mon Tue Wed Thu Fri Sat Sun))[ gm->wday() ];
use Time::gmtime w(:FIELDS;
printf "The day in Greenwich is %s\n",
(qw(Sun Mon Tue Wed Thu Fri Sat Sun))[ gm_wday() ];
$now = gmctime();
use Time::gmtime;
use File::stat;
$date_string = gmctime(stat($file)->mtime);
=head1 DESCRIPTION
This module's default exports override the core gmtime() function,
replacing it with a version that returns "Time::tm" objects.
This object has methods that return the similarly named structure field
name from the C's tm structure from F<time.h>; namely sec, min, hour,
mday, mon, year, wday, yday, and isdst.
You may also import all the structure fields directly into your namespace
as regular variables using the :FIELDS import tag. (Note that this
still overrides your core functions.) Access these fields as variables
named with a preceding C<tm_> in front their method names. Thus,
C<$tm_obj-E<gt>mday()> corresponds to $tm_mday if you import the fields.
The gmctime() function provides a way of getting at the
scalar sense of the original CORE::gmtime() function.
To access this functionality without the core overrides,
pass the C<use> an empty import list, and then access
function functions with their full qualified names.
On the other hand, the built-ins are still available
via the C<CORE::> pseudo-package.
=head1 NOTE
While this class is currently implemented using the Class::Struct
module to build a struct-like class, you shouldn't rely upon this.
=head1 AUTHOR
Tom Christiansen
--- NEW FILE: Local.pm ---
package Time::Local;
require Exporter;
use Carp;
use Config;
use strict;
use integer;
use vars qw( $VERSION @ISA @EXPORT @EXPORT_OK );
$VERSION = '1.11';
$VERSION = eval $VERSION;
@ISA = qw( Exporter );
@EXPORT = qw( timegm timelocal );
@EXPORT_OK = qw( timegm_nocheck timelocal_nocheck );
my @MonthDays = (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
# Determine breakpoint for rolling century
my $ThisYear = (localtime())[5];
my $Breakpoint = ($ThisYear + 50) % 100;
my $NextCentury = $ThisYear - $ThisYear % 100;
$NextCentury += 100 if $Breakpoint < 50;
my $Century = $NextCentury - 100;
my $SecOff = 0;
my (%Options, %Cheat, %Min, %Max);
my ($MinInt, $MaxInt);
if ($^O eq 'MacOS') {
# time_t is unsigned...
$MaxInt = (1 << (8 * $Config{intsize})) - 1;
$MinInt = 0;
} else {
$MaxInt = ((1 << (8 * $Config{intsize} - 2))-1)*2 + 1;
$MinInt = -$MaxInt - 1;
# On Win32 (and others?) time_t appears to be signed, but negative
# epochs still don't work. - XXX - this is experimental
$MinInt = 0
unless defined ((localtime(-1))[0]);
}
$Max{Day} = ($MaxInt >> 1) / 43200;
$Min{Day} = $MinInt ? -($Max{Day} + 1) : 0;
$Max{Sec} = $MaxInt - 86400 * $Max{Day};
$Min{Sec} = $MinInt - 86400 * $Min{Day};
# Determine the EPOC day for this machine
my $Epoc = 0;
if ($^O eq 'vos') {
# work around posix-977 -- VOS doesn't handle dates in
# the range 1970-1980.
$Epoc = _daygm((0, 0, 0, 1, 0, 70, 4, 0));
}
elsif ($^O eq 'MacOS') {
no integer;
# MacOS time() is seconds since 1 Jan 1904, localtime
# so we need to calculate an offset to apply later
$Epoc = 693901;
$SecOff = timelocal(localtime(0)) - timelocal(gmtime(0));
$Epoc += _daygm(gmtime(0));
}
else {
$Epoc = _daygm(gmtime(0));
}
%Cheat=(); # clear the cache as epoc has changed
sub _daygm {
$_[3] + ($Cheat{pack("ss", at _[4,5])} ||= do {
my $month = ($_[4] + 10) % 12;
my $year = $_[5] + 1900 - $month/10;
365*$year + $year/4 - $year/100 + $year/400 + ($month*306 + 5)/10 - $Epoc
});
}
sub _timegm {
my $sec = $SecOff + $_[0] + 60 * $_[1] + 3600 * $_[2];
no integer;
$sec + 86400 * &_daygm;
}
sub _zoneadjust {
my ($day, $sec, $time) = @_;
$sec = $sec + _timegm(localtime($time)) - $time;
if ($sec >= 86400) { $day++; $sec -= 86400; }
if ($sec < 0) { $day--; $sec += 86400; }
($day, $sec);
}
sub timegm {
my ($sec,$min,$hour,$mday,$month,$year) = @_;
if ($year >= 1000) {
$year -= 1900;
}
elsif ($year < 100 and $year >= 0) {
$year += ($year > $Breakpoint) ? $Century : $NextCentury;
}
unless ($Options{no_range_check}) {
if (abs($year) >= 0x7fff) {
$year += 1900;
croak "Cannot handle date ($sec, $min, $hour, $mday, $month, *$year*)";
}
croak "Month '$month' out of range 0..11" if $month > 11 or $month < 0;
my $md = $MonthDays[$month];
# ++$md if $month == 1 and $year % 4 == 0 and
# ($year % 100 != 0 or ($year + 1900) % 400 == 0);
++$md unless $month != 1 or $year % 4 or !($year % 400);
croak "Day '$mday' out of range 1..$md" if $mday > $md or $mday < 1;
croak "Hour '$hour' out of range 0..23" if $hour > 23 or $hour < 0;
croak "Minute '$min' out of range 0..59" if $min > 59 or $min < 0;
croak "Second '$sec' out of range 0..59" if $sec > 59 or $sec < 0;
}
my $days = _daygm(undef, undef, undef, $mday, $month, $year);
my $xsec = $sec + $SecOff + 60*$min + 3600*$hour;
unless ($Options{no_range_check}
or ($days > $Min{Day} or $days == $Min{Day} and $xsec >= $Min{Sec})
and ($days < $Max{Day} or $days == $Max{Day} and $xsec <= $Max{Sec}))
{
warn "Day too small - $days > $Min{Day}\n" if $days < $Min{Day};
warn "Day too big - $days > $Max{Day}\n" if $days > $Max{Day};
warn "Sec too small - $days < $Min{Sec}\n" if $days < $Min{Sec};
warn "Sec too big - $days > $Max{Sec}\n" if $days > $Max{Sec};
$year += 1900;
croak "Cannot handle date ($sec, $min, $hour, $mday, $month, $year)";
}
no integer;
$xsec + 86400 * $days;
}
sub timegm_nocheck {
local $Options{no_range_check} = 1;
&timegm;
}
sub timelocal {
# Adjust Max/Min allowed times to fit local time zone and call timegm
local ($Max{Day}, $Max{Sec}) = _zoneadjust($Max{Day}, $Max{Sec}, $MaxInt);
local ($Min{Day}, $Min{Sec}) = _zoneadjust($Min{Day}, $Min{Sec}, $MinInt);
my $ref_t = &timegm;
# Calculate first guess with a one-day delta to avoid localtime overflow
my $delta = ($_[5] < 100)? 86400 : -86400;
my $loc_t = _timegm(localtime( $ref_t + $delta )) - $delta;
# Is there a timezone offset from GMT or are we done
my $zone_off = $ref_t - $loc_t
or return $loc_t;
# This hack is needed to always pick the first matching time
# during a DST change when time would otherwise be ambiguous
$zone_off -= 3600 if ($delta > 0 && $ref_t >= 3600);
# Adjust for timezone
$loc_t = $ref_t + $zone_off;
# Are we close to a DST change or are we done
my $dst_off = $ref_t - _timegm(localtime($loc_t))
or return $loc_t;
# Adjust for DST change
$loc_t += $dst_off;
return $loc_t if $dst_off >= 0;
# for a negative offset from GMT, and if the original date
# was a non-extent gap in a forward DST jump, we should
# now have the wrong answer - undo the DST adjust;
my ($s,$m,$h) = localtime($loc_t);
$loc_t -= $dst_off if $s != $_[0] || $m != $_[1] || $h != $_[2];
$loc_t;
}
sub timelocal_nocheck {
local $Options{no_range_check} = 1;
&timelocal;
}
1;
__END__
=head1 NAME
Time::Local - efficiently compute time from local and GMT time
=head1 SYNOPSIS
$time = timelocal($sec,$min,$hour,$mday,$mon,$year);
$time = timegm($sec,$min,$hour,$mday,$mon,$year);
=head1 DESCRIPTION
These routines are the inverse of built-in perl functions localtime()
and gmtime(). They accept a date as a six-element array, and return
the corresponding time(2) value in seconds since the system epoch
(Midnight, January 1, 1970 GMT on Unix, for example). This value can
be positive or negative, though POSIX only requires support for
positive values, so dates before the system's epoch may not work on
all operating systems.
It is worth drawing particular attention to the expected ranges for
the values provided. The value for the day of the month is the actual day
(ie 1..31), while the month is the number of months since January (0..11).
This is consistent with the values returned from localtime() and gmtime().
The timelocal() and timegm() functions perform range checking on the
input $sec, $min, $hour, $mday, and $mon values by default. If you'd
rather they didn't, you can explicitly import the timelocal_nocheck()
and timegm_nocheck() functions.
use Time::Local 'timelocal_nocheck';
{
# The 365th day of 1999
print scalar localtime timelocal_nocheck 0,0,0,365,0,99;
# The twenty thousandth day since 1970
print scalar localtime timelocal_nocheck 0,0,0,20000,0,70;
# And even the 10,000,000th second since 1999!
print scalar localtime timelocal_nocheck 10000000,0,0,1,0,99;
}
Your mileage may vary when trying these with minutes and hours,
and it doesn't work at all for months.
Strictly speaking, the year should also be specified in a form consistent
with localtime(), i.e. the offset from 1900.
In order to make the interpretation of the year easier for humans,
however, who are more accustomed to seeing years as two-digit or four-digit
values, the following conventions are followed:
=over 4
=item *
Years greater than 999 are interpreted as being the actual year,
rather than the offset from 1900. Thus, 1964 would indicate the year
Martin Luther King won the Nobel prize, not the year 3864.
=item *
Years in the range 100..999 are interpreted as offset from 1900,
so that 112 indicates 2012. This rule also applies to years less than zero
(but see note below regarding date range).
=item *
Years in the range 0..99 are interpreted as shorthand for years in the
rolling "current century," defined as 50 years on either side of the current
year. Thus, today, in 1999, 0 would refer to 2000, and 45 to 2045,
but 55 would refer to 1955. Twenty years from now, 55 would instead refer
to 2055. This is messy, but matches the way people currently think about
two digit dates. Whenever possible, use an absolute four digit year instead.
=back
The scheme above allows interpretation of a wide range of dates, particularly
if 4-digit years are used.
Please note, however, that the range of dates that can be actually be handled
depends on the size of an integer (time_t) on a given platform.
Currently, this is 32 bits for most systems, yielding an approximate range
from Dec 1901 to Jan 2038.
Both timelocal() and timegm() croak if given dates outside the supported
range.
=head2 Ambiguous Local Times (DST)
Because of DST changes, there are many time zones where the same local
time occurs for two different GMT times on the same day. For example,
in the "Europe/Paris" time zone, the local time of 2001-10-28 02:30:00
can represent either 2001-10-28 00:30:00 GMT, B<or> 2001-10-28
01:30:00 GMT.
When given an ambiguous local time, the timelocal() function should
always return the epoch for the I<earlier> of the two possible GMT
times.
=head2 Non-Existent Local Times (DST)
When a DST change causes a locale clock to skip one hour forward,
there will be an hour's worth of local times that don't exist. Again,
for the "Europe/Paris" time zone, the local clock jumped from
2001-03-25 01:59:59 to 2001-03-25 03:00:00.
If the timelocal() function is given a non-existent local time, it
will simply return an epoch value for the time one hour later.
=head2 Negative Epoch Values
Negative epoch (time_t) values are not officially supported by the
POSIX standards, so this module's tests do not test them. On some
systems, they are known not to work. These include MacOS (pre-OSX)
and Win32.
On systems which do support negative epoch values, this module should
be able to cope with dates before the start of the epoch, down the
minimum value of time_t for the system.
=head1 IMPLEMENTATION
These routines are quite efficient and yet are always guaranteed to agree
with localtime() and gmtime(). We manage this by caching the start times
of any months we've seen before. If we know the start time of the month,
we can always calculate any time within the month. The start times
are calculated using a mathematical formula. Unlike other algorithms
that do multiple calls to gmtime().
timelocal() is implemented using the same cache. We just assume that we're
translating a GMT time, and then fudge it when we're done for the timezone
and daylight savings arguments. Note that the timezone is evaluated for
each date because countries occasionally change their official timezones.
Assuming that localtime() corrects for these changes, this routine will
also be correct.
=head1 BUGS
The whole scheme for interpreting two-digit years can be considered a bug.
=head1 SUPPORT
Support for this module is provided via the datetime at perl.org
email list. See http://lists.perl.org/ for more details.
Please submit bugs using the RT system at rt.cpan.org, or as a last
resort, to the datetime at perl.org list.
=head1 AUTHOR
This module is based on a Perl 4 library, timelocal.pl, that was
included with Perl 4.036, and was most likely written by Tom
Christiansen.
The current version was written by Graham Barr.
It is now being maintained separately from the Perl core by Dave
Rolsky, <autarch at urth.org>.
=cut
--- NEW FILE: localtime.t ---
#!./perl
BEGIN {
chdir 't' if -d 't';
@INC = '../lib';
}
BEGIN {
our $haslocal;
eval { my $n = localtime 0 };
$haslocal = 1 unless $@ && $@ =~ /unimplemented/;
unless ($haslocal) { print "1..0 # Skip: no localtime\n"; exit 0 }
}
BEGIN {
our @localtime = localtime 0; # This is the function localtime.
unless (@localtime) { print "1..0 # Skip: localtime failed\n"; exit 0 }
}
print "1..10\n";
use Time::localtime;
print "ok 1\n";
my $localtime = localtime 0 ; # This is the OO localtime.
print "not " unless $localtime->sec == $localtime[0];
print "ok 2\n";
print "not " unless $localtime->min == $localtime[1];
print "ok 3\n";
print "not " unless $localtime->hour == $localtime[2];
print "ok 4\n";
print "not " unless $localtime->mday == $localtime[3];
print "ok 5\n";
print "not " unless $localtime->mon == $localtime[4];
print "ok 6\n";
print "not " unless $localtime->year == $localtime[5];
print "ok 7\n";
print "not " unless $localtime->wday == $localtime[6];
print "ok 8\n";
print "not " unless $localtime->yday == $localtime[7];
print "ok 9\n";
print "not " unless $localtime->isdst == $localtime[8];
print "ok 10\n";
--- NEW FILE: Local.t ---
#!./perl
BEGIN {
if ($ENV{PERL_CORE}){
chdir('t') if -d 't';
@INC = ('.', '../lib');
}
}
use strict;
use Config;
use Test;
use Time::Local;
# Set up time values to test
my @time =
(
#year,mon,day,hour,min,sec
[1970, 1, 2, 00, 00, 00],
[1980, 2, 28, 12, 00, 00],
[1980, 2, 29, 12, 00, 00],
[1999, 12, 31, 23, 59, 59],
[2000, 1, 1, 00, 00, 00],
[2010, 10, 12, 14, 13, 12],
# leap day
[2020, 2, 29, 12, 59, 59],
[2030, 7, 4, 17, 07, 06],
# The following test fails on a surprising number of systems
# so it is commented out. The end of the Epoch for a 32-bit signed
# implementation of time_t should be Jan 19, 2038 03:14:07 UTC.
# [2038, 1, 17, 23, 59, 59], # last full day in any tz
);
my @bad_time =
(
# month too large
[1995, 13, 01, 01, 01, 01],
# day too large
[1995, 02, 30, 01, 01, 01],
# hour too large
[1995, 02, 10, 25, 01, 01],
# minute too large
[1995, 02, 10, 01, 60, 01],
# second too large
[1995, 02, 10, 01, 01, 60],
);
my @neg_time =
(
# test negative epochs for systems that handle it
[ 1969, 12, 31, 16, 59, 59 ],
[ 1950, 04, 12, 9, 30, 31 ],
);
# Use 3 days before the start of the epoch because with Borland on
# Win32 it will work for -3600 _if_ your time zone is +01:00 (or
# greater).
my $neg_epoch_ok = defined ((localtime(-259200))[0]) ? 1 : 0;
# use vmsish 'time' makes for oddness around the Unix epoch
if ($^O eq 'VMS') {
$time[0][2]++;
$neg_epoch_ok = 0; # time_t is unsigned
}
my $tests = (@time * 12);
$tests += @neg_time * 12;
$tests += @bad_time;
$tests += 8;
$tests += 2 if $ENV{PERL_CORE};
$tests += 5 if $ENV{MAINTAINER};
plan tests => $tests;
for (@time, @neg_time) {
my($year, $mon, $mday, $hour, $min, $sec) = @$_;
$year -= 1900;
$mon--;
if ($^O eq 'vos' && $year == 70) {
skip(1, "skipping 1970 test on VOS.\n") for 1..6;
} elsif ($year < 70 && ! $neg_epoch_ok) {
skip(1, "skipping negative epoch.\n") for 1..6;
} else {
my $year_in = $year < 70 ? $year + 1900 : $year;
my $time = timelocal($sec,$min,$hour,$mday,$mon,$year_in);
my($s,$m,$h,$D,$M,$Y) = localtime($time);
ok($s, $sec, 'timelocal second');
ok($m, $min, 'timelocal minute');
ok($h, $hour, 'timelocal hour');
ok($D, $mday, 'timelocal day');
ok($M, $mon, 'timelocal month');
ok($Y, $year, 'timelocal year');
}
if ($^O eq 'vos' && $year == 70) {
skip(1, "skipping 1970 test on VOS.\n") for 1..6;
} elsif ($year < 70 && ! $neg_epoch_ok) {
skip(1, "skipping negative epoch.\n") for 1..6;
} else {
my $year_in = $year < 70 ? $year + 1900 : $year;
my $time = timegm($sec,$min,$hour,$mday,$mon,$year_in);
my($s,$m,$h,$D,$M,$Y) = gmtime($time);
ok($s, $sec, 'timegm second');
ok($m, $min, 'timegm minute');
ok($h, $hour, 'timegm hour');
ok($D, $mday, 'timegm day');
ok($M, $mon, 'timegm month');
ok($Y, $year, 'timegm year');
}
}
for (@bad_time) {
my($year, $mon, $mday, $hour, $min, $sec) = @$_;
$year -= 1900;
$mon--;
eval { timegm($sec,$min,$hour,$mday,$mon,$year) };
ok($@, qr/.*out of range.*/, 'invalid time caused an error');
}
ok(timelocal(0,0,1,1,0,90) - timelocal(0,0,0,1,0,90), 3600,
'one hour difference between two calls to timelocal');
ok(timelocal(1,2,3,1,0,100) - timelocal(1,2,3,31,11,99), 24 * 3600,
'one day difference between two calls to timelocal');
# Diff beween Jan 1, 1980 and Mar 1, 1980 = (31 + 29 = 60 days)
ok(timegm(0,0,0, 1, 2, 80) - timegm(0,0,0, 1, 0, 80), 60 * 24 * 3600,
'60 day difference between two calls to timegm');
# bugid #19393
# At a DST transition, the clock skips forward, eg from 01:59:59 to
# 03:00:00. In this case, 02:00:00 is an invalid time, and should be
# treated like 03:00:00 rather than 01:00:00 - negative zone offsets used
# to do the latter
{
my $hour = (localtime(timelocal(0, 0, 2, 7, 3, 102)))[2];
# testers in US/Pacific should get 3,
# other testers should get 2
ok($hour == 2 || $hour == 3, 1, 'hour should be 2 or 3');
}
if ($neg_epoch_ok) {
eval { timegm(0,0,0,29,1,1900) };
ok($@, qr/Day '29' out of range 1\.\.28/);
eval { timegm(0,0,0,29,1,1904) };
ok($@, '');
} else {
skip(1, "skipping negative epoch.\n") for 1..2;
}
# round trip was broken for edge cases
if ($^O eq "aix" && $Config{osvers} =~ m/^4\.3\./) {
skip( 1, "No fix expected for edge case test for $_ on AIX 4.3") for qw( timegm timelocal );
} else {
ok(sprintf('%x', timegm(gmtime(0x7fffffff))), sprintf('%x', 0x7fffffff),
'0x7fffffff round trip through gmtime then timegm');
ok(sprintf('%x', timelocal(localtime(0x7fffffff))), sprintf('%x', 0x7fffffff),
'0x7fffffff round trip through localtime then timelocal');
}
if ($ENV{MAINTAINER}) {
eval { require POSIX; POSIX::tzset() };
if ($@) {
skip( 1, "Cannot call POSIX::tzset() on this platform\n" ) for 1..3;
}
else {
local $ENV{TZ} = 'Europe/Vienna';
POSIX::tzset();
# 2001-10-28 02:30:00 - could be either summer or standard time,
# prefer earlier of the two, in this case summer
my $time = timelocal(0, 30, 2, 28, 9, 101);
ok($time, 1004229000,
'timelocal prefers earlier epoch in the presence of a DST change');
local $ENV{TZ} = 'America/Chicago';
POSIX::tzset();
# Same local time in America/Chicago. There is a transition
# here as well.
$time = timelocal(0, 30, 1, 28, 9, 101);
ok($time, 1004250600,
'timelocal prefers earlier epoch in the presence of a DST change');
$time = timelocal(0, 30, 2, 1, 3, 101);
ok($time, 986113800,
'timelocal for non-existent time gives you the time one hour later');
local $ENV{TZ} = 'Australia/Sydney';
POSIX::tzset();
# 2001-03-25 02:30:00 in Australia/Sydney. This is the transition
# _to_ summer time. The southern hemisphere transitions are
# opposite those of the northern.
$time = timelocal(0, 30, 2, 25, 2, 101);
ok($time, 985447800,
'timelocal prefers earlier epoch in the presence of a DST change');
$time = timelocal(0, 30, 2, 28, 9, 101);
ok($time, 1004200200,
'timelocal for non-existent time gives you the time one hour later');
}
}
if ($ENV{PERL_CORE}) {
package test;
require 'timelocal.pl';
# need to get ok() from main package
::ok(timegm(0,0,0,1,0,80), main::timegm(0,0,0,1,0,80),
'timegm in timelocal.pl');
::ok(timelocal(1,2,3,4,5,88), main::timelocal(1,2,3,4,5,88),
'timelocal in timelocal.pl');
}
--- NEW FILE: tm.pm ---
package Time::tm;
use strict;
our $VERSION = '1.00';
use Class::Struct qw(struct);
struct('Time::tm' => [
map { $_ => '$' } qw{ sec min hour mday mon year wday yday isdst }
]);
1;
__END__
=head1 NAME
Time::tm - internal object used by Time::gmtime and Time::localtime
=head1 SYNOPSIS
Don't use this module directly.
=head1 DESCRIPTION
This module is used internally as a base class by Time::localtime And
Time::gmtime functions. It creates a Time::tm struct object which is
addressable just like's C's tm structure from F<time.h>; namely with sec,
min, hour, mday, mon, year, wday, yday, and isdst.
This class is an internal interface only.
=head1 AUTHOR
Tom Christiansen
More information about the dslinux-commit
mailing list