dslinux/user/perl/ext/Socket/t Socket.t socketpair.t
cayenne
dslinux_cayenne at user.in-berlin.de
Mon Dec 4 17:59:42 CET 2006
Update of /cvsroot/dslinux/dslinux/user/perl/ext/Socket/t
In directory antilope:/tmp/cvs-serv17422/ext/Socket/t
Added Files:
Socket.t socketpair.t
Log Message:
Adding fresh perl source to HEAD to branch from
--- NEW FILE: socketpair.t ---
#!./perl -w
my $child;
my $can_fork;
my $has_perlio;
BEGIN {
chdir 't' if -d 't';
@INC = '../lib';
require Config; import Config;
$can_fork = $Config{'d_fork'}
|| ($^O eq 'MSWin32' && $Config{useithreads}
&& $Config{ccflags} =~ /-DPERL_IMPLICIT_SYS\b/);
if ($^O eq "hpux" or $Config{'extensions'} !~ /\bSocket\b/ &&
!(($^O eq 'VMS') && $Config{d_socket})) {
print "1..0\n";
exit 0;
}
# Too many things in this test will hang forever if something is wrong,
# so we need a self destruct timer. And IO can hang despite an alarm.
# This is convoluted, but we must fork before Test::More, else child's
# Test::More thinks that it ran no tests, and prints a message to that
# effect
if( $can_fork) {
my $parent = $$;
$child = fork;
die "Fork failed" unless defined $child;
if (!$child) {
$SIG{INT} = sub {exit 0}; # You have 60 seconds. Your time starts now.
my $must_finish_by = time + 60;
my $remaining;
while (($remaining = $must_finish_by - time) > 0) {
sleep $remaining;
}
warn "Something unexpectedly hung during testing";
kill "INT", $parent or die "Kill failed: $!";
exit 1;
}
}
unless ($has_perlio = find PerlIO::Layer 'perlio') {
print <<EOF;
# Since you don't have perlio you might get failures with UTF-8 locales.
EOF
}
}
use Socket;
use Test::More;
use strict;
use warnings;
use Errno;
my $skip_reason;
if( !$Config{d_alarm} ) {
plan skip_all => "alarm() not implemented on this platform";
} elsif( !$can_fork ) {
plan skip_all => "fork() not implemented on this platform";
} else {
# This should fail but not die if there is real socketpair
eval {socketpair LEFT, RIGHT, -1, -1, -1};
if ($@ =~ /^Unsupported socket function "socketpair" called/ ||
$! =~ /^The operation requested is not supported./) { # Stratus VOS
plan skip_all => 'No socketpair (real or emulated)';
} else {
eval {AF_UNIX};
if ($@ =~ /^Your vendor has not defined Socket macro AF_UNIX/) {
plan skip_all => 'No AF_UNIX';
} else {
plan tests => 45;
}
}
}
# But we'll install an alarm handler in case any of the races below fail.
$SIG{ALRM} = sub {die "Unexpected alarm during testing"};
ok (socketpair (LEFT, RIGHT, AF_UNIX, SOCK_STREAM, PF_UNSPEC),
"socketpair (LEFT, RIGHT, AF_UNIX, SOCK_STREAM, PF_UNSPEC)")
or print "# \$\! = $!\n";
if ($has_perlio) {
binmode(LEFT, ":bytes");
binmode(RIGHT, ":bytes");
}
my @left = ("hello ", "world\n");
my @right = ("perl ", "rules!"); # Not like I'm trying to bias any survey here.
foreach (@left) {
# is (syswrite (LEFT, $_), length $_, "write " . _qq ($_) . " to left");
is (syswrite (LEFT, $_), length $_, "syswrite to left");
}
foreach (@right) {
# is (syswrite (RIGHT, $_), length $_, "write " . _qq ($_) . " to right");
is (syswrite (RIGHT, $_), length $_, "syswrite to right");
}
# stream socket, so our writes will become joined:
my ($buffer, $expect);
$expect = join '', @right;
undef $buffer;
is (read (LEFT, $buffer, length $expect), length $expect, "read on left");
is ($buffer, $expect, "content what we expected?");
$expect = join '', @left;
undef $buffer;
is (read (RIGHT, $buffer, length $expect), length $expect, "read on right");
is ($buffer, $expect, "content what we expected?");
ok (shutdown(LEFT, SHUT_WR), "shutdown left for writing");
# This will hang forever if eof is buggy, and alarm doesn't interrupt system
# Calls. Hence the child process minder.
SKIP: {
skip "SCO Unixware / OSR have a bug with shutdown",2 if $^O =~ /^(?:svr|sco)/;
local $SIG{ALRM} = sub { warn "EOF on right took over 3 seconds" };
local $TODO = "Known problems with unix sockets on $^O"
if $^O eq 'hpux' || $^O eq 'super-ux';
alarm 3;
$! = 0;
ok (eof RIGHT, "right is at EOF");
local $TODO = "Known problems with unix sockets on $^O"
if $^O eq 'unicos' || $^O eq 'unicosmk';
is ($!, '', 'and $! should report no error');
alarm 60;
}
my $err = $!;
$SIG{PIPE} = 'IGNORE';
{
local $SIG{ALRM}
= sub { warn "syswrite to left didn't fail within 3 seconds" };
alarm 3;
# Split the system call from the is() - is() does IO so
# (say) a flush may do a seek which on a pipe may disturb errno
my $ans = syswrite (LEFT, "void");
$err = $!;
is ($ans, undef, "syswrite to shutdown left should fail");
alarm 60;
}
{
# This may need skipping on some OSes - restoring value saved above
# should help
$! = $err;
ok (($!{EPIPE} or $!{ESHUTDOWN}), '$! should be EPIPE or ESHUTDOWN')
or printf "\$\!=%d(%s)\n", $err, $err;
}
my @gripping = (chr 255, chr 127);
foreach (@gripping) {
is (syswrite (RIGHT, $_), length $_, "syswrite to right");
}
ok (!eof LEFT, "left is not at EOF");
$expect = join '', @gripping;
undef $buffer;
is (read (LEFT, $buffer, length $expect), length $expect, "read on left");
is ($buffer, $expect, "content what we expected?");
ok (close LEFT, "close left");
ok (close RIGHT, "close right");
# And now datagrams
# I suspect we also need a self destruct time-bomb for these, as I don't see any
# guarantee that the stack won't drop a UDP packet, even if it is for localhost.
SKIP: {
skip "No usable SOCK_DGRAM for socketpair", 24 if ($^O =~ /^(MSWin32|os2)\z/);
local $TODO = "socketpair not supported on $^O" if $^O eq 'nto';
ok (socketpair (LEFT, RIGHT, AF_UNIX, SOCK_DGRAM, PF_UNSPEC),
"socketpair (LEFT, RIGHT, AF_UNIX, SOCK_DGRAM, PF_UNSPEC)")
or print "# \$\! = $!\n";
if ($has_perlio) {
binmode(LEFT, ":bytes");
binmode(RIGHT, ":bytes");
}
foreach (@left) {
# is (syswrite (LEFT, $_), length $_, "write " . _qq ($_) . " to left");
is (syswrite (LEFT, $_), length $_, "syswrite to left");
}
foreach (@right) {
# is (syswrite (RIGHT, $_), length $_, "write " . _qq ($_) . " to right");
is (syswrite (RIGHT, $_), length $_, "syswrite to right");
}
# stream socket, so our writes will become joined:
my ($total);
$total = join '', @right;
foreach $expect (@right) {
undef $buffer;
is (sysread (LEFT, $buffer, length $total), length $expect, "read on left");
is ($buffer, $expect, "content what we expected?");
}
$total = join '', @left;
foreach $expect (@left) {
undef $buffer;
is (sysread (RIGHT, $buffer, length $total), length $expect, "read on right");
is ($buffer, $expect, "content what we expected?");
}
ok (shutdown(LEFT, 1), "shutdown left for writing");
# eof uses buffering. eof is indicated by a sysread of zero.
# but for a datagram socket there's no way it can know nothing will ever be
# sent
SKIP: {
skip "$^O does length 0 udp reads", 2 if ($^O eq 'os390');
my $alarmed = 0;
local $SIG{ALRM} = sub { $alarmed = 1; };
print "# Approximate forever as 3 seconds. Wait 'forever'...\n";
alarm 3;
undef $buffer;
is (sysread (RIGHT, $buffer, 1), undef,
"read on right should be interrupted");
is ($alarmed, 1, "alarm should have fired");
}
alarm 30;
#ok (eof RIGHT, "right is at EOF");
foreach (@gripping) {
is (syswrite (RIGHT, $_), length $_, "syswrite to right");
}
$total = join '', @gripping;
foreach $expect (@gripping) {
undef $buffer;
is (sysread (LEFT, $buffer, length $total), length $expect, "read on left");
is ($buffer, $expect, "content what we expected?");
}
ok (close LEFT, "close left");
ok (close RIGHT, "close right");
} # end of DGRAM SKIP
kill "INT", $child or warn "Failed to kill child process $child: $!";
exit 0;
--- NEW FILE: Socket.t ---
#!./perl
BEGIN {
chdir 't' if -d 't';
@INC = '../lib';
require Config; import Config;
if ($Config{'extensions'} !~ /\bSocket\b/ &&
!(($^O eq 'VMS') && $Config{d_socket})) {
print "1..0\n";
exit 0;
}
$has_alarm = $Config{d_alarm};
}
use Socket;
print "1..17\n";
$has_echo = $^O ne 'MSWin32';
$alarmed = 0;
sub arm { $alarmed = 0; alarm(shift) if $has_alarm }
sub alarmed { $alarmed = 1 }
$SIG{ALRM} = 'alarmed' if $has_alarm;
if (socket(T,PF_INET,SOCK_STREAM,6)) {
print "ok 1\n";
arm(5);
my $host = $^O eq 'MacOS' || ($^O eq 'irix' && $Config{osvers} == 5) ?
'127.0.0.1' : 'localhost';
my $localhost = inet_aton($host);
if ($has_echo && defined $localhost && connect(T,pack_sockaddr_in(7,$localhost))){
arm(0);
print "ok 2\n";
print "# Connected to " .
inet_ntoa((unpack_sockaddr_in(getpeername(T)))[1])."\n";
arm(5);
syswrite(T,"hello",5);
arm(0);
arm(5);
$read = sysread(T,$buff,10); # Connection may be granted, then closed!
arm(0);
while ($read > 0 && length($buff) < 5) {
# adjust for fact that TCP doesn't guarantee size of reads/writes
arm(5);
$read = sysread(T,$buff,10,length($buff));
arm(0);
}
print(($read == 0 || $buff eq "hello") ? "ok 3\n" : "not ok 3\n");
}
else {
print "# You're allowed to fail tests 2 and 3 if\n";
print "# the echo service has been disabled or if your\n";
print "# gethostbyname() cannot resolve your localhost.\n";
print "# 'Connection refused' indicates disabled echo service.\n";
print "# 'Interrupted system call' indicates a hanging echo service.\n";
print "# Error: $!\n";
print "ok 2 - skipped\n";
print "ok 3 - skipped\n";
}
}
else {
print "# Error: $!\n";
print "not ok 1\n";
}
if( socket(S,PF_INET,SOCK_STREAM,6) ){
print "ok 4\n";
arm(5);
if ($has_echo && connect(S,pack_sockaddr_in(7,INADDR_LOOPBACK))){
arm(0);
print "ok 5\n";
print "# Connected to " .
inet_ntoa((unpack_sockaddr_in(getpeername(S)))[1])."\n";
arm(5);
syswrite(S,"olleh",5);
arm(0);
arm(5);
$read = sysread(S,$buff,10); # Connection may be granted, then closed!
arm(0);
while ($read > 0 && length($buff) < 5) {
# adjust for fact that TCP doesn't guarantee size of reads/writes
arm(5);
$read = sysread(S,$buff,10,length($buff));
arm(0);
}
print(($read == 0 || $buff eq "olleh") ? "ok 6\n" : "not ok 6\n");
}
else {
print "# You're allowed to fail tests 5 and 6 if\n";
print "# the echo service has been disabled.\n";
print "# 'Interrupted system call' indicates a hanging echo service.\n";
print "# Error: $!\n";
print "ok 5 - skipped\n";
print "ok 6 - skipped\n";
}
}
else {
print "# Error: $!\n";
print "not ok 4\n";
}
# warnings
$SIG{__WARN__} = sub {
++ $w if $_[0] =~ /^6-ARG sockaddr_in call is deprecated/ ;
} ;
$w = 0 ;
sockaddr_in(1,2,3,4,5,6) ;
print ($w == 1 ? "not ok 7\n" : "ok 7\n") ;
use warnings 'Socket' ;
sockaddr_in(1,2,3,4,5,6) ;
print ($w == 1 ? "ok 8\n" : "not ok 8\n") ;
# Thest that whatever we give into pack/unpack_sockaddr retains
# the value thru the entire chain.
if((inet_ntoa((unpack_sockaddr_in(pack_sockaddr_in(100,inet_aton("10.250.230.10"))))[1])) eq '10.250.230.10') {
print "ok 9\n";
} else {
print "not ok 9\n";
}
print ((inet_ntoa(inet_aton("10.20.30.40")) eq "10.20.30.40") ? "ok 10\n" : "not ok 10\n");
print ((inet_ntoa(v10.20.30.40) eq "10.20.30.40") ? "ok 11\n" : "not ok 11\n");
{
my ($port,$addr) = unpack_sockaddr_in(pack_sockaddr_in(100,v10.10.10.10));
print (($port == 100) ? "ok 12\n" : "not ok 12\n");
print ((inet_ntoa($addr) eq "10.10.10.10") ? "ok 13\n" : "not ok 13\n");
}
eval { inet_ntoa(v10.20.30.400) };
print (($@ =~ /^Wide character in Socket::inet_ntoa at/) ? "ok 14\n" : "not ok 14\n");
if (sockaddr_family(pack_sockaddr_in(100,inet_aton("10.250.230.10"))) == AF_INET) {
print "ok 15\n";
} else {
print "not ok 15\n";
}
eval { sockaddr_family("") };
print (($@ =~ /^Bad arg length for Socket::sockaddr_family, length is 0, should be at least \d+/) ? "ok 16\n" : "not ok 16\n");
if ($^O eq 'linux') {
# see if we can handle abstract sockets
my $test_abstract_socket = chr(0) . '/tmp/test-perl-socket';
my $addr = sockaddr_un ($test_abstract_socket);
my ($path) = sockaddr_un ($addr);
if ($test_abstract_socket eq $path) {
print "ok 17\n";
}
else {
$path =~ s/\0/\\0/g;
print "# got <$path>\n";
print "not ok 17\n";
}
} else {
# doesn't have abstract socket support
print "ok 17 - skipped on this platform\n";
}
More information about the dslinux-commit
mailing list