dslinux/user/perl/NetWare/bat Buildtype.bat SetCodeWar.bat SetNWBld.bat Setnlmsdk.bat ToggleD2.bat

[cayenne]

Update of /cvsroot/dslinux/dslinux/user/perl/NetWare/bat
In directory antilope:/tmp/cvs-serv17422/NetWare/bat

Added Files:
	Buildtype.bat SetCodeWar.bat SetNWBld.bat Setnlmsdk.bat 
	ToggleD2.bat 
Log Message:
Adding fresh perl source to HEAD to branch from

--- NEW FILE: SetCodeWar.bat ---
@echo off
@rem AUTHOR: sgp & apc
@rem CREATED: 24th July 2000
@rem LAST REVISED: 6th April 2001
@rem LAST REVISED: 22nd May 2002
@rem AUTHOR: apc
@rem Batch file to set the path to CodeWarrior directories
@rem This file is called from SetNWBld.bat.

if "%1" == "/now" goto now
if "%1" == "" goto Usage
if "%1" == "/?" goto usage
if "%1" == "/h" goto usage

set CODEWAR=%1
ECHO CODEWAR=%1

call buildtype r
@echo Buildtype set to Release type

set MWCIncludes=%1\include
@echo MWCIncludes=%1\include
set MWLibraries=%1\lib
@echo MWLibraries=%1\lib
set MWLibraryFiles=%1\lib\nwpre.obj;%1\lib\mwcrtld.lib
@echo MWLibraryFiles=%1\lib\nwpre.obj;%1\lib\mwcrtld.lib

set PATH=%PATH%;%1\bin;
@echo PATH=%PATH%;%1\bin;

goto exit

:now
@echo CODEWAR=%CODEWAR%
goto exit

:Usage
 @echo on
 @echo "Usage: setCodeWar <Path to CodeWarrior binaries>"
 @echo "Usage: setCodeWar /now" - To display current setting
 @echo Ex. setCodeWar d:\CodeWar

:exit

--- NEW FILE: Setnlmsdk.bat ---
@echo off
@rem AUTHOR: sgp
@rem CREATED: 24th July 2000
@rem LAST REVISED: 6th April 2001
@rem Batch file to set the path to NetWare SDK
@rem This file is called from SetNWBld.bat. 

if "%1" == "/now" goto now
if "%1" == "" goto Usage
if "%1" == "/?" goto usage
if "%1" == "/h" goto usage

set NLMSDKBASE=%1
echo NLMSDKBASE set to %1

goto exit

:now
@echo NLMSDKBASE=%NLMSDKBASE%
goto exit

:Usage
 @echo on
 @echo "Usage: setnlmsdk <path to NetWare sdk>"
 @echo "Usage: setnlmsdk /now" - To display current setting
 @echo Ex. setnlmsdk e:\sdkcd14\nwsdk

:exit

--- NEW FILE: ToggleD2.bat ---
@echo off
@rem AUTHOR: sgp
@rem CREATED: 23rd August 1999
@rem LAST REVISED: 6th April 2001
@rem Batch file to toggle D2 flag for debugging in case of debug build 
@rem and remove in case of release build.
@rem This file is called from BuildType.bat

if "%1" == "" goto Usage

if "%1" == "/now" goto now
if "%1" == "on" goto yes
if "%1" == "off" goto no
if "%1" == "/?" goto usage
if "%1" == "/h" goto usage

Rem Invalid input and so display the help message
goto Usage

:now
if "%USE_D2%" == "" echo USE_D2 is removed, uses /d1
if not "%USE_D2%"  == "" echo USE_D2 is set, uses /d2
goto exit

:yes
Set USE_D2=1
echo ....USE_D2 is set, uses /d2
goto exit

:no
Set USE_D2=
echo ....USE_D2 is removed. uses /d1
goto exit

:Usage
 @echo on
 @echo "Usage: ToggleD2 [on|off]"
 @echo "Usage: ToggleD2 /now" - To display current setting

:exit

--- NEW FILE: SetNWBld.bat ---
@echo off
@rem AUTHOR: apc
@rem CREATED: Thu 18th Jan 2001 09:18:08
@rem LAST REVISED: 6th April 2001
@rem LAST REVISED: 22nd May 2002
@rem Batch file to set the path to Default Buildtype,NetWare SDK, CodeWarrior directories 
@rem This file calls buildtype with release as defualt,setnlmsdk.bat, setCodeWar.bat & setmpksdk.bat and MpkBuild with off as default

REM If no parameters are passed, display usage
if "%1" == "" goto Usage
if "%1" == "/?" goto Usage
if "%1" == "/h" goto Usage

REM Display the current settings
if "%1" == "/now" goto now

REM If na is passed, don't set that parameter
if "%1" == "na" goto skip_nlmsdk_msg

:setnwsdk
call setnlmsdk %1
goto skip_nlmsdk_nomsg

:skip_nlmsdk_msg
@echo Retaining NLMSDKBASE=%NLMSDKBASE%

:skip_nlmsdk_nomsg
if "%2" == "" goto err_exit
if "%2" == "na" goto skip_cw_msg

:setcodewar
call setcodewar %2
goto skip_cw_nomsg

:skip_cw_msg
@echo Retaining CODEWAR=%CODEWAR%
goto exit

:skip_cw_nomsg
goto exit

:err_exit
@echo Not Enough Parameters
goto Usage

:now
@echo NLMSDKBASE=%NLMSDKBASE%
@echo CODEWAR=%CODEWAR%
goto exit

:Usage
 @echo on
 @echo "Usage: setnwdef <path to NetWare SDK> <path to CodeWarrior dir>"
 @echo "Usage: setnwdef /now" - To display current setting
 @echo Pass na if you don't want to change a setting
 @echo Ex. setnwbld d:\ndk\nwsdk na
 @echo Ex. setnwbld na d:\codewar

:exit

--- NEW FILE: Buildtype.bat ---
@echo off
@rem AUTHOR: sgp
@rem CREATED: 24th July 2000
@rem LAST REVISED: 6th April 2001
@rem Batch file to set debug/release build and toggle D2 flag for 
@rem debugging in case of debug build.
@rem This file calls ToggleD2.bat which switches b/n d2 & d1 flags

if "%1" == "" goto Usage
if "%1" == "/now" goto now
if "%1" == "/?" goto usage
if "%1" == "/h" goto usage

if "%1" == "r" goto set_type_rel
if "%1" == "R" goto set_type_rel

if "%1" == "d" goto set_type_dbg
if "%1" == "D" goto set_type_dbg

Rem Invalid input and so display the help message
goto Usage
 
:set_type_rel
set MAKE_TYPE=Release
echo ....Build set to %MAKE_TYPE%
goto set_d2_off

:set_type_dbg
set MAKE_TYPE=Debug
echo ....Build set to %MAKE_TYPE%
if "%2" == "" goto set_d2_off
call ToggleD2 %2

goto exit

:set_d2_off
call ToggleD2 off
goto exit

:now
if "%MAKE_TYPE%" == "" echo MAKE_TYPE is not set, hence it defaults to Release build
if not "%MAKE_TYPE%" == "" echo Current build type is - %MAKE_TYPE%
call ToggleD2 /now
goto exit

:Usage
 @echo on
 @echo "Usage: buildtype r/R|d/D [on/off]"  
 @echo      on/off - Toggling only for D2 flag during debug build
 @echo "Usage: buildtype /now"  - To display current setting
 @echo Ex. buildtype d on

:exit